// traveller.txt by Lazarus
// When a flag is set, NPC moves to a waypoint. When it arrives it will stop, and face a direction.
// This is pretty customizable, just remove the talking state and use it however you want.
// Memory Cells:
//   Cell 0 - Unused
//   Cell 1,2 - Stuff done flag. If both 0, nothing. Otherwise when this 
//     is killed, set to 1. (Example: If cell 1 is 3 and cell 2 is 5, when
//     creature is killed, sets SDF(3,5) to 1.)
//   Cell 3 - Dialogue node to start with if talked to. if left at 0, this
//     character doesn't talk.
//   Cell 4 - Waypoint that the character walks too
//   Cell 5,6 - Stuff done flag. If set to 1 will make creature start walking
//   Cell 7 - Direction to face when reaches destination. use appendixes to know which numbers go with directions

begincreaturescript;

variables;


body;

beginstate INIT_STATE;
set_mobility(ME,0);
	break;

beginstate DEAD_STATE;
	// Set the appropriate stuff done flag for this character being dead
	if ((get_memory_cell(1) != 0) || (get_memory_cell(2) != 0))
		set_flag(get_memory_cell(1),get_memory_cell(2),1);
break;

beginstate START_STATE; 
	// if I have a target for some reason, go attack it
	if (target_ok()) {
		if (dist_to_char(get_target()) <= 16)
			set_state(3);
			else set_target(ME,-1);
		}
	
	// Look for a target, attack it if visible
	if (select_target(ME,8,0)) {
		do_attack();
		set_state(3);
		}
		
	// Have I been hit? Strike back!
	if (who_hit_me() >= 0) {
		set_target(ME,who_hit_me());
		do_attack();
		set_state(3);
		}
	
	// Otherwise, walk to waypoint
	if(get_flag(get_memory_cell(5),get_memory_cell(6)) == 1) {
			set_mobility(ME,1);
		if (approach_waypoint(ME,get_memory_cell(4),0) == 1) {
			stop_moving(ME);
				set_character_facing(ME,(get_memory_cell(7)));
				force_instant_terrain_redraw();				
			set_mobility(ME,0); }
}
		
		

	// if we're in combat and the above didn't give me anything to do, just
	// stop now. Otherwise, game will keep running script, and that eats up CPU time.
	if (am_i_doing_action() == FALSE)
		end_combat_turn();
break;

beginstate 3; // attacking
	if (target_ok() == FALSE)
		set_state(START_STATE);
	do_attack();
break;

beginstate TALKING_STATE;
	print_str_color("You should speak with shaman Brup.",2);
break;